#Denoiser script for interlaced video using MDegrain2

#This is the recommended script for VHS as of January 25, 2011



Loadplugin("C:\Program Files\AviSynth 2.5\plugins\MVTools\mvtools2.dll")

LoadPlugin("c:\Program Files\AviSynth 2.5\plugins\CNR\Cnr2.dll")



SetMTMode(5) #Only use this line if you have the multi-threaded version of AVISynth



#Modify this line to point to your video file

#Change AssumeBFF() to AssumeTFF() for HD video

source=AVISource("E:\frameserver.avi").killaudio().AssumeBFF()



SetMTMode(2,0) #Only use this line if you have the multi-threaded version of AVISynth



#Only use chroma restoration for analog source material

#chroma=source.Cnr2("oxx",8,16,191,100,255,32,255,false) #VHS

chroma=source #Use this line for digital video



#Set overlap (second parameter in MDegrain function) to 0, 2, 4, 8. Higher number=better, but slower

#For VHS, 4,0 seems to work better than 8,2. Most of difference is in shadows.

#However, 8,0 is good enough and MUCH faster. 8,2 doesn't seem to make much difference on VHS.

#Set the last number to 1 if the video contains flicker -- this makes script run at about 10% of the normal speed.



output=MDegrain2i2(chroma,8,0,0)



#stackhorizontal(source,output)  #Use this line to do before/after comparison

return output



#-------------------------------



function MDegrain2i2(clip source, int "blksize", int "overlap", int "dct")

{



Vshift=2 # 2 lines per bobbed-field per tape generation (PAL); original=2; copy=4 etc

Hshift=0 # determine experimentally -- I've used values up to 12 (can be + or -)

overlap=default(overlap,0) # overlap value (0 to 4 for blksize=8)

dct=default(dct,0) # use dct=1 for clip with light flicker



fields=source.SeparateFields() # separate by fields because this function is for interlaced video



#This line gets rid of vertical chroma halo -- eliminate if this isn't a problem (i.e., for digital video)

fixed_fields=MergeChroma(fields,crop(fields,Hshift,Vshift,0,0).addborders(0,0,Hshift,Vshift))

#fixed_fields=fields #Use this line instead of the one above when doing digital video



super = fixed_fields.MSuper(pel=2, sharp=1)

backward_vec2 = super.MAnalyse(isb = true, delta = 2, blksize=blksize, overlap=overlap, dct=dct)

forward_vec2 = super.MAnalyse(isb = false, delta = 2, blksize=blksize, overlap=overlap, dct=dct)

backward_vec4 = super.MAnalyse(isb = true, delta = 4, blksize=blksize, overlap=overlap, dct=dct)

forward_vec4 = super.MAnalyse(isb = false, delta = 4, blksize=blksize, overlap=overlap, dct=dct)



#Change thSAD to increase/decrease de-noising

MDegrain2(fixed_fields,super, backward_vec2,forward_vec2,backward_vec4,forward_vec4,thSAD=400) #400=original setting

unsharpmask(60,3,0) #This provides "clever" sharpening that brings out detail without adding obnoxious sharpening artifacts

Weave()  #Convert fields back into interlaced video



}