@Howard-Vigorita thanks! I created the folder, used Notepad, changed the extension to .xml and the transition is there.

Wonderful!

Some days, the one brain cell I have left is working, other days....

 

Some days, the one brain cell I have left is working, other days....

..... you are certainly not alone......😏

@boundless-beta The transitions you made are amazing! In the meantime, did you make anything new for us?

@boundless-beta The transitions you made are amazing! In the meantime, did you make anything new for us?

To give a few ideas for transitions I would like to have/use in Vegas:

This one I think is cool!

Yeah, looks like from a 360 cam :)
I also like to use transitions in Vegas like the best from Proshow gold modern ones.

I am more interested in this style of 3D transition :

yess! possible with GL programming?

yess! possible with GL programming?

Already a lot is possible when modifying the swish transition from @boundless-beta earlier in this thread.

yes, so even rotate in 3D space is possible. great to know.

now i have to learn programming :)

Thank you @boundless-beta for updating the beautiful Exponential Swish transition code that now can work with AMD Devices.

For users who have a glitch issue in AMD Devices, please update the code.

I can't thank you enough to you because how many recent videos that I create using this, but it really helps me on telling the story and 'at least' modernize the look of transition, plus the UI interface makes it easy to customize it so instead of zoom in only, zoom out or doing panning is also possible:

https://www.instagram.com/p/Cxz5-4yvkJh/

+1 to @boundless-beta!!

Previously an error on Exponential Swish:

....
// Name: Exponential Swish
// Author: Boundless
// License: MIT#define PI 3.14159265
uniform float kParamFloat0;// =0.8; [-1, 1]
 ....

due to no enter new line.

@boundless-beta, I edit your post and code so it should be safe from error now:

....
// Name: Exponential Swish
// Author: Boundless
// License: MIT

#define PI 3.14159265
uniform float kParamFloat0;// =0.8; [-1, 1]
​​​​​​​ ....

Vegas 21 introduced adjustment events and Offset＆Wrap plug-in, which enables users to make transitions such as Swish, Slide and Zoom without programming.

Maybe it would be a good idea to create an post named "Adjustment-Event Transitions gallery".

First scripting, now transitions, I really think team VEGAS needs to keep putting more customization options into the hands of users who can write their own code, which then creates a thriving community of users sharing their customizations. I think it would be cool, for instance, for a user to be able to create their own version of the preview window, with added functions, or create custom skins for VEGAS. that last one especially, you will never please all users with aesthetic decisions made, but if you let them customize the look themselves completely, they can skin it however they like and everyone is happy.

but there should be also an appreciation section for those who are not developers but still working for some growth of VEGAS with doing there small contribute somehow. Like one of them is @jetdv sir who is creating scripts and helping others in there scripts. Even i create two tools for VEGAS users which can be helpful in fast workflow. i.e. Quick Render & MiniTools.

I posted my new created tool Quick Render as separate thread. But no one is focusing on it.

So my point is there should be a USER CREATIONS section in this community page. So everyone can check those creations at priorities.

Vegas 21 introduced adjustment events and Offset＆Wrap plug-in, which enables users to make transitions such as Swish, Slide and Zoom without programming.

Maybe it would be a good idea to create an post named "Adjustment-Event Transitions gallery".

this is the idea i was thinking about

Thats odd. If I use the copy from above I get the error too. Maybe something in the formatting.

This is the original code and it works fine. Be sure to delete the default code and dont miss off any opening // and closing } 's.

// author: Hewlett-Packard
// license: BSD 3 Clause
// Adapted by Sergey Kosarevsky from:
// http://rectalogic.github.io/webvfx/examples_2transition-shader-pagecurl_8html-example.html

/*
Copyright (c) 2010 Hewlett-Packard Development Company, L.P. All rights reserved.

Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are
met:

   * Redistributions of source code must retain the above copyright
     notice, this list of conditions and the following disclaimer.
   * Redistributions in binary form must reproduce the above
     copyright notice, this list of conditions and the following disclaimer
     in the documentation and/or other materials provided with the
     distribution.
   * Neither the name of Hewlett-Packard nor the names of its
     contributors may be used to endorse or promote products derived from
     this software without specific prior written permission.

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
"AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
in vec2 texCoord;
*/

const float MIN_AMOUNT = -0.16;
const float MAX_AMOUNT = 1.5;
float amount = progress * (MAX_AMOUNT - MIN_AMOUNT) + MIN_AMOUNT;

const float PI = 3.141592653589793;

const float scale = 512.0;
const float sharpness = 3.0;

float cylinderCenter = amount;
// 360 degrees * amount
float cylinderAngle = 2.0 * PI * amount;

const float cylinderRadius = 1.0 / PI / 2.0;

vec3 hitPoint(float hitAngle, float yc, vec3 point, mat3 rrotation)
{
        float hitPoint = hitAngle / (2.0 * PI);
        point.y = hitPoint;
        return rrotation * point;
}

vec4 antiAlias(vec4 color1, vec4 color2, float distanc)
{
        distanc *= scale;
        if (distanc < 0.0) return color2;
        if (distanc > 2.0) return color1;
        float dd = pow(1.0 - distanc / 2.0, sharpness);
        return ((color2 - color1) * dd) + color1;
}

float distanceToEdge(vec3 point)
{
        float dx = abs(point.x > 0.5 ? 1.0 - point.x : point.x);
        float dy = abs(point.y > 0.5 ? 1.0 - point.y : point.y);
        if (point.x < 0.0) dx = -point.x;
        if (point.x > 1.0) dx = point.x - 1.0;
        if (point.y < 0.0) dy = -point.y;
        if (point.y > 1.0) dy = point.y - 1.0;
        if ((point.x < 0.0 || point.x > 1.0) && (point.y < 0.0 || point.y > 1.0)) return sqrt(dx * dx + dy * dy);
        return min(dx, dy);
}

vec4 seeThrough(float yc, vec2 p, mat3 rotation, mat3 rrotation)
{
        float hitAngle = PI - (acos(yc / cylinderRadius) - cylinderAngle);
        vec3 point = hitPoint(hitAngle, yc, rotation * vec3(p, 1.0), rrotation);
        if (yc <= 0.0 && (point.x < 0.0 || point.y < 0.0 || point.x > 1.0 || point.y > 1.0))
        {
            return getToColor(p);
        }

        if (yc > 0.0) return getFromColor(p);

        vec4 color = getFromColor(point.xy);
        vec4 tcolor = vec4(0.0);

        return antiAlias(color, tcolor, distanceToEdge(point));
}

vec4 seeThroughWithShadow(float yc, vec2 p, vec3 point, mat3 rotation, mat3 rrotation)
{
        float shadow = distanceToEdge(point) * 30.0;
        shadow = (1.0 - shadow) / 3.0;

        if (shadow < 0.0) shadow = 0.0; else shadow *= amount;

        vec4 shadowColor = seeThrough(yc, p, rotation, rrotation);
        shadowColor.r -= shadow;
        shadowColor.g -= shadow;
        shadowColor.b -= shadow;

        return shadowColor;
}

vec4 backside(float yc, vec3 point)
{
        vec4 color = getFromColor(point.xy);
        float gray = (color.r + color.b + color.g) / 15.0;
        gray += (8.0 / 10.0) * (pow(1.0 - abs(yc / cylinderRadius), 2.0 / 10.0) / 2.0 + (5.0 / 10.0));
        color.rgb = vec3(gray);
        return color;
}

vec4 behindSurface(vec2 p, float yc, vec3 point, mat3 rrotation)
{
        float shado = (1.0 - ((-cylinderRadius - yc) / amount * 7.0)) / 6.0;
        shado *= 1.0 - abs(point.x - 0.5);

        yc = (-cylinderRadius - cylinderRadius - yc);

        float hitAngle = (acos(yc / cylinderRadius) + cylinderAngle) - PI;
        point = hitPoint(hitAngle, yc, point, rrotation);

        if (yc < 0.0 && point.x >= 0.0 && point.y >= 0.0 && point.x <= 1.0 && point.y <= 1.0 && (hitAngle < PI || amount > 0.5))
        {
                shado = 1.0 - (sqrt(pow(point.x - 0.5, 2.0) + pow(point.y - 0.5, 2.0)) / (71.0 / 100.0));
                shado *= pow(-yc / cylinderRadius, 3.0);
                shado *= 0.5;
        }
        else
        {
                shado = 0.0;
        }
        return vec4(getToColor(p).rgb - shado, 1.0);
}

vec4 transition(vec2 p) {

  const float angle = 100.0 * PI / 180.0;
        float c = cos(-angle);
        float s = sin(-angle);

        mat3 rotation = mat3( c, s, 0,
                                                                -s, c, 0,
                                                                -0.801, 0.8900, 1
                                                                );
        c = cos(angle);
        s = sin(angle);

        mat3 rrotation = mat3(    c, s, 0,
                                                                        -s, c, 0,
                                                                        0.98500, 0.985, 1
                                                                );

        vec3 point = rotation * vec3(p, 1.0);

        float yc = point.y - cylinderCenter;

        if (yc < -cylinderRadius)
        {
                // Behind surface
                return behindSurface(p,yc, point, rrotation);
        }

        if (yc > cylinderRadius)
        {
                // Flat surface
                return getFromColor(p);
        }

        float hitAngle = (acos(yc / cylinderRadius) + cylinderAngle) - PI;

        float hitAngleMod = mod(hitAngle, 2.0 * PI);
        if ((hitAngleMod > PI && amount < 0.5) || (hitAngleMod > PI/2.0 && amount < 0.0))
        {
                return seeThrough(yc, p, rotation, rrotation);
        }

        point = hitPoint(hitAngle, yc, point, rrotation);

        if (point.x < 0.0 || point.y < 0.0 || point.x > 1.0 || point.y > 1.0)
        {
                return seeThroughWithShadow(yc, p, point, rotation, rrotation);
        }

        vec4 color = backside(yc, point);

        vec4 otherColor;
        if (yc < 0.0)
        {
                float shado = 1.0 - (sqrt(pow(point.x - 0.5, 2.0) + pow(point.y - 0.5, 2.0)) / 0.71);
                shado *= pow(-yc / cylinderRadius, 3.0);
                shado *= 0.5;
                otherColor = vec4(0.0, 0.0, 0.0, shado);
        }
        else
        {
                otherColor = getFromColor(p);
        }

        color = antiAlias(color, otherColor, cylinderRadius - abs(yc));

        vec4 cl = seeThroughWithShadow(yc, p, point, rotation, rrotation);
        float dist = distanceToEdge(point);

        return antiAlias(color, cl, dist);
}

Thanks @paul-marshall, I thought that copy-paste that into a code section is fine...but something change... anyway...I'll delete my post above to avoid any confusion.

Ref: https://www.vegascreativesoftware.info/us/forum/book-page-turn-effect--137158/#ca913369

Also,

@iEmby, the adjustment event gallery is here too: https://www.vegascreativesoftware.info/us/forum/adjustment-event-filters-transition-gallery--143622/